La Couronne de Cuivre

RPG, Roleplay, Actualités, Mods, Traductions. De la Porte de Baldur aux confins de Féérune, la Couronne de Cuivre est incontournable !
https://www.baldursgateworld.fr/

[WeiDU] Message d'erreur incompréhensible dans WeiDU.log

https://www.baldursgateworld.fr/viewtopic.php?t=30338

Page 1 sur 1

[WeiDU] Message d'erreur incompréhensible dans WeiDU.log

Posté : jeu. 24 nov. 2016, 03:04
par Freddy_Gwendo
Ça fait plus d'une journée que je tente en vain de résoudre un problème assez pénible.

Il n'est pas bloquant car il n'empêche ni l'installation, ni la désinstallation du mod, mais il me gonfle passablement. En gros, WeiDU ne semble pas reconnaître le nom de mon composant une fois qu'il a été installé.

Voici le WeiDU.Log après installation :

Code : Tout sélectionner

// Log of Currently Installed WeiDU Mods
// The top of the file is the 'oldest' mod
// ~TP2_File~ #language_number #component_number // [Subcomponent Name -> ] Component Name [ : Version]
~BG2EETRANS/BG2EETRANS.TP2~ #0 #0 // Initialisation: v0.4.67.2
~BG2EETRANSBG2EETRANSINSTALL.TP2~ #0 #1001 // Textes repris de BGII-ToB: v0.4.67.2
~BG2EETRANSBG2EETRANSINSTALL.TP2~ #0 #1002 // Textes repris de BGEE: v0.4.67.2
~BG2EETRANSBG2EETRANSINSTALL.TP2~ #0 #1003 // Ajout de la langue au menu + credits (BG2EE V2.0 et plus): v0.4.67.2
~DIAMANT_ETERNEL/SETUP-DIAMANT_ETERNEL.TP2~ #0 #0 // [color="#FFFF00"]Modification des fichiers IDS : OBLIGATOIRE !: Beta 0.1[/color]
Tout s'est passé sans problème, ni warning dans le DEBUG.

Puis, j'installe un autre mod :

Code : Tout sélectionner

// Log of Currently Installed WeiDU Mods
// The top of the file is the 'oldest' mod
// ~TP2_File~ #language_number #component_number // [Subcomponent Name -> ] Component Name [ : Version]
~BG2EETRANS/BG2EETRANS.TP2~ #0 #0 // Initialisation: v0.4.67.2
~BG2EETRANSBG2EETRANSINSTALL.TP2~ #0 #1001 // Textes repris de BGII-ToB: v0.4.67.2
~BG2EETRANSBG2EETRANSINSTALL.TP2~ #0 #1002 // Textes repris de BGEE: v0.4.67.2
~BG2EETRANSBG2EETRANSINSTALL.TP2~ #0 #1003 // Ajout de la langue au menu + credits (BG2EE V2.0 et plus): v0.4.67.2
~DIAMANT_ETERNEL/SETUP-DIAMANT_ETERNEL.TP2~ #0 #0 // [color="#FFFF00"]UNDEFINED STRING:   @10100: Beta 0.1[/color]
~SKIPCHATEAUIRENICUS/SETUP-SKIPCHATEAUIRENICUS.TP2~ #2 #0 // Esquiver le Donjon d'Irenicus: 2.2
Et le DEBUG se termine ainsi :

Code : Tout sélectionner

Saving This Log:
BG2EETRANS/BG2EETRANS.TP2  0  0 Installed
BG2EETRANSBG2EETRANSINSTALL.TP2  0 1001 Installed
BG2EETRANSBG2EETRANSINSTALL.TP2  0 1002 Installed
BG2EETRANSBG2EETRANSINSTALL.TP2  0 1003 Installed
DIAMANT_ETERNEL/SETUP-DIAMANT_ETERNEL.TP2  0  0 Installed
SKIPCHATEAUIRENICUS/SETUP-SKIPCHATEAUIRENICUS.TP2  2  0 Installed ~Esquiver le Donjon d'Irenicus~
[bg2eetrans/language/fr_FR/setup.tra] has 69 translation strings
[color="#FFFF00"]ERROR: No translation provided for @10100
Continuing despite error.[/color]
[SkipChateauIrenicus/languages/french/setup.tra] has 61 translation strings
[SkipChateauIrenicus/languages/french/mod.tra] has 27 translation strings

[color="#FFFF00"]INSTALLATION REUSSIE Esquiver le Donjon d'Irenicus[/color]
Pourtant, le fichier GW_setup.TRA contient bien le string @10100 et semble bien chargé puisque le fichier DEBUG affiche bien les messages qu'il contient.

Si quelqu'un a une idée, je suis preneur car je commence à me fracasser le crâne contre les murs.

Voici mon tp2 :

Code : Tout sélectionner

BACKUP ~Diamant_Eternel/Backup~
AUTHOR ~Gwendolyne, [url]http://www.baldursgateworld.fr/lacouronne/members/freddy_gwendo.html~[/url]

//MODDER

VERSION ~Beta 0.1~

AUTO_TRA ~Diamant_Eternel/Tra/%s~

ALWAYS

/* ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++ *
 *	PATCH_IF (ou ACTION_IF) GW_debug_variable :                                                                                                     *
 *  -------------------------------------------                                                                                                     *
 *	INTÉGRATION d'un message dans un fichier .txt et/ou dans le fichier DEBUG pour débogage pendant le développement :                              *
 *	0 = aucun message	-	1 = vérifie certainss points clé intermédiaires	-	2 = tous les points clé intermédiaires	-	3 = tous les messages.  *
 * ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++ */
	OUTER_SET GW_debug_variable = 1

	INCLUDE ~%MOD_FOLDER%/Lib/GW_PreReqs.tpa~	// Bibliothèque de fonctions et de macros définissant les variables de compatibilité avec les jeux et les autres mods.
	INCLUDE ~%MOD_FOLDER%/Lib/GW_Variables.tpa~	// Bibliothèque de fonctions et de macros définissant des variables à partir des fichiers ids.
	INCLUDE ~%MOD_FOLDER%/Lib/GW_Fonctions.tpa~	// Bibliothèque de fonctions et de macros générales.


/* Copies tra files into the autotra folder (to leave the originals untouched) */

/* Converts tra files to UTF-8 */
	ACTION_IF NOT VARIABLE_IS_SET cd_always THEN BEGIN	// Convertir une seule fois les fichiers .TRA
		OUTER_SET cd_always = 1
		ACTION_DEFINE_ARRAY GW#noconvert BEGIN GW_Setup END
		ACTION_DEFINE_ARRAY GW#reload BEGIN GW_Items END 
		LAF HANDLE_CHARSETS 
			INT_VAR	infer_charsets = 1
			STR_VAR	tra_path = EVAL ~%MOD_FOLDER%/Tra~
				noconvert_array = GW#noconvert
				reload_array = GW#reload
				default_language = francais
				iconv_path = EVAL ~%MOD_FOLDER%/tools/iconv~
		END
	END

/* TRAs declared in LANGUAGE must be reloaded - by hand, because of the copying (for non-EE version */
	LOAD_TRA ~%MOD_FOLDER%/Tra/%LANGUAGE%/GW_Setup.tra~

END	// of ALWAYS block


LANGUAGE	~Francais~	~francais~	~%MOD_FOLDER%/Tra/francais/GW_Setup.tra~


BEGIN @10100	// ~Modification des fichiers IDS : OBLIGATOIRE !~

REQUIRE_PREDICATE	((GAME_IS ~tob bgt~) 
			&&	(MOD_IS_INSTALLED "SETUP-BG2FIXPACK.TP2" "0") 
			&&	(FILE_EXISTS ~tobex.dll~))
			OR  (GAME_IS ~BG2EE~)
@10010	// ~====== Ce module requiert soit l'installation de l'extension Trone de Bhaal, de ToBEx et du BG2 Fixpack, soit une version Enhanced du jeu (BG2EE). ======~


/* ------------------------------------------------ *
 *  Vérification de la présence des mods 1PP et IA  *
 * ------------------------------------------------ */
ACTION_IF ((GW_BGT = 1) OR (GW_ToB = 1)) AND ($GWCompat(~1PP~) STR_CMP "Y") BEGIN	// 1ppv4 : Additional Shield Animations
	PRINT @10011
	PRINT @10012
	ACTION_READLN test1PP
	OUTER_WHILE NOT(IS_AN_INT %test1PP%) || (%test1PP% > 2) || (%test1PP% < 1) BEGIN
		PRINT @10012
		ACTION_READLN test1PP
	END				// of OUTER_WHILE NOT(IS_AN_INT %test1PP%) || (%test1PP% > 2) || (%test1PP% < 1)
	ACTION_IF test1PP = 2 THEN BEGIN
		FAIL @10013	// ~ABANDON de l'INSTALLATION car 1PP n'est pas installé.~
	END
END					// of ACTION_IF NOT (MOD_IS_INSTALLED ~1pp.tp2~ 101)

ACTION_IF ((GW_BGT = 1) OR (GW_ToB = 1)) AND ($GWCompat(~IA~) STR_CMP "Y") BEGIN	// Infinity Animations installé
	PRINT @10021
	PRINT @10022
	ACTION_READLN testIA
	OUTER_WHILE NOT(IS_AN_INT %testIA%) || (%testIA% > 2) || (%testIA% < 1) BEGIN
		PRINT @10022
		ACTION_READLN testIA
	END				// of OUTER_WHILE NOT(IS_AN_INT %testIA%) || (%testIA% > 2) || (%testIA% < 1)
	ACTION_IF testIA = 2 THEN BEGIN
		FAIL @10023	// ~ABANDON de l'INSTALLATION car Infinity Animations n'est pas installé.~
	END
END					// of ACTION_IF NOT (MOD_IS_INSTALLED ~setup-infinityanimations.tp2~ 0)


/* -------------------------------------------------------------------------------------------------------------------- *
 *  Petite assurance pour que les créatures et les objets utilisant la palette étendue de 1PP ne plantent pas le jeu !  *
 * -------------------------------------------------------------------------------------------------------------------- */
ACTION_FOR_EACH GWPalette IN MPALETTE MPAL256 BEGIN
	ACTION_IF FILE_EXISTS_IN_GAME ~%GWPalette%.bmp~ BEGIN
		COPY_EXISTING - ~%GWPalette%.bmp~ ~override/%GWPalette%.bmp~
			PATCH_MATCH ~%GWPalette%~ WITH
				MPALETTE BEGIN	SET size1PP = 9272 END
				DEFAULT			SET size1PP = 196664
			END
		OUTER_SET sizePal = %SOURCE_SIZE%
		PRINT "%GWPalette%.bmp = %sizePal% - 1PP = %size1PP%"
		ACTION_IF (sizePal != %size1PP%) BEGIN
			PRINT @10014	// ~Copie du fichier %SOURCE_FILE% : palette étendue de 1PP.~
			COPY ~%MOD_FOLDER%/%GWPalette%.bmp~      ~override/%GWPalette%.bmp~
		END
	END
END


INCLUDE ~%MOD_FOLDER%/Lib/GW_ids.tph~			// Modification et extension des fichiers ids.
INCLUDE ~%MOD_FOLDER%/Lib/GW_Animate.tph~		// Ajout des nouvelles animations

Posté : jeu. 24 nov. 2016, 12:56
par Haplo74
Hello,

Peut-être que cela n'a rien à voir avec ton souci, mais lors de mes essais d'installation, j'ai constaté qu'il y avait des problèmes avec le mod Azengaard Tactical Encounter, avec certains fichiers comprenant le caractère underscore (_).
J'ai l'impression que WeiDU le considère comme un caractère spécial...
As-tu essayé de renommer ton DIAMANT_ETERNEL en DIAMANTETERNEL ?

Haplo74

Posté : jeu. 24 nov. 2016, 20:29
par Freddy_Gwendo
WeiDU a beaucoup de mal avec les caractères spéciaux mais non, ça ne vient pas de là, sinon l'installation de generalized_biffing aurait été plus que problématique. Seuls les espaces sont à déconseiller dans les noms de répertoire, surtout si on utilise le BWS.
Ceci dit, je me pose la question depuis un bon moment et il est plus que probable que je finisse par suivre ton conseil. En fait, j'attendais de pondre une version de test pour le faire. ;)


Sinon, bonne nouvelle, j'ai trouvé l'origine du problème et, comme souvent, c'est tout bête. Alors voici un bon conseil à destination des moddeurs :

>> N'UTILISEZ JAMAIS LA VARIABLE %MOD_FOLDER% dans la déclaration de langage à utiliser.

Pour simplifier l'installation, je l'ai employée chaque fois que possible mais manifestement, WeiDU ne la reconnaît pas à ce moment du traitement. Il m'a suffit de remplacer

Code : Tout sélectionner

LANGUAGE	~Francais~	~francais~	~[color="#FFFF00"]%MOD_FOLDER%[/color]/Tra/francais/GW_Setup.tra~
par

Code : Tout sélectionner

LANGUAGE	~Francais~	~francais~	~[color="#FFFF00"]Diamant_Eternel[/color]/Tra/francais/GW_Setup.tra~
pour que tout retourne dans l'ordre.

Tout est bien qui finit bien... ^^

Posté : jeu. 24 nov. 2016, 23:18
par Isaya
En lisant ton premier message, avant de voir le dernier, l'emploi de %MOD_FOLDER% à cet endroit m'a sauté aux yeux. L'explication est en fin de compte assez simple. Quand tu installes Skip Chateau Irenicus, %MOD_FOLDER% vaut SKIPCHATEAUIRENICUS et SKIPCHATEAUIRENICUS/Tra/francais/GW_Setup.tra n'existe pas pour que WeiDU y trouve le texte @10100.
Heures au format UTC+01:00
Page 1 sur 1

Développé par phpBB® Forum Software © phpBB Limited

Traduit par phpBB-fr.com