[WeiDU] Problème de "Label..." pendant la compilation d'un dialogue

[Klare]

Bonjour bonjour.
Alors que je préparais tranquillement le squelette de mon dialogue j'ai eu la mauvaise surprise de me retrouver devant un bug de Weidu, qui me refusait une formule de condition, alors que j'avais 4 lignes plus tôt quelque chose de quasi-identique et fonctionnel, enfin bref suite a quelques Clic et 2 heures j'ai vaincu le problème.

Maintenant j'ai la chance... de voir apparaitre un problème de label, soit :

► Afficher le texte

Compiling 1 script ...
Compiling 1 dialogue file ...
ERROR: Cannot resolve internal symbolic label [Klareenemy0401] for DLG [#ZKLARE]

Known labels: Klareintro0101 Klareintro0102 Klareintro0103 Klareintro0104 Klares
ilence0101 Klaresilence0102 Klarepresentation0101 Klaremensonge0101 Klareverite0
101 Klareverite0102 Klareverite0103 Klareinteru0101
ERROR: postprocessing [#ZKLARE]: Failure("cannot resolve label")
Stopping installation because of error.

Mais là, j'ai beau secouer le diable... pas moyen de faire refonctionner mon mod. Et puisque je ne comprend pas le pourquoi du problème je viens pleurer les larmes chaudes de mon corps fripé ici

Voici pour les courageux mon .D
Merci d'avance a ceux qui pourrons m'expliquer le pourquoi du bug de 'label'

► Afficher le texte

BEGIN "#ZKlare" //Partie qui permet le cheminement dans les differents dialogues de Klare
//Deux premiers chiffres : ID du dialogue en entier, deux derniers : ID du bloc

//////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
// Dialogues d'introduction - 01 //
//////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
// Partie 1 crise de nerfs de la bestiole enfin liberée de sa cage
IF ~NumTimesTalkedTo(0)~ THEN BEGIN Klareintro0101
SAY @1301001
IF ~~ THEN REPLY @2301001 GOTO Klareintro0102
IF ~~ THEN REPLY @2301002 GOTO Klareintro0102 //silence
IF ~~ THEN REPLY @2301003 GOTO Klareenemy0401 //Klaire devient hostile
END
IF ~~ THEN BEGIN Klareintro0102
SAY @1301002
IF ~~ THEN REPLY @2301004 GOTO Klareintro0103
IF ~~ THEN REPLY @2301002 GOTO Klareintro0103 //silence
IF ~~ THEN REPLY @2301003 GOTO Klareenemy0401 //Klaire devient hostile
END
IF ~~ THEN BEGIN Klareintro0103
SAY @1301003
IF ~~ THEN REPLY @2301005 GOTO Klareintro0104
IF ~~ THEN REPLY @2301002 GOTO Klareintro0104 //silence
IF ~~ THEN REPLY @2301006 GOTO Klareenemy0401 //Klaire devient hostile
END
IF ~~ THEN BEGIN Klareintro0104
SAY @1301004
IF ~~ THEN REPLY @2301007 GOTO Klarepresentation0101
IF ~~ THEN REPLY @2301002 GOTO Klaresilence0101 //silence
IF ~~ THEN REPLY @2301008 GOTO Klareenemy0401 //Klare devient hostile
END

// Partie 1.5 le perso est trop calme
IF ~~ THEN BEGIN Klaresilence0101
SAY @1301005
IF ~~ THEN REPLY @2301009 GOTO Klarepresentation0101
IF ~~ THEN REPLY @2301002 GOTO Klaresilence0102 //silence
IF ~~ THEN REPLY @2301010 GOTO Klarefuit0403 //Klare s'en va
END
IF ~~ THEN BEGIN Klaresilence0102
SAY @1301006
IF ~~ THEN DO ~SetGlobal("#ZKlareangry","GLOBAL",1)~ EXIT //Klare s'en va
END

// Partie 2 presentations.
IF ~~ THEN BEGIN Klarepresentation0101
SAY @1301007
IF ~~ THEN REPLY @2301011 GOTO Klaremensonge0101
IF ~~ THEN REPLY @2301012 GOTO Klareverite0101
END

IF ~~ THEN BEGIN Klaremensonge0101
SAY @1301008
IF ~~ THEN REPLY @2301013 GOTO Klaresilence0102
IF ~~ THEN REPLY @2301012 GOTO Klareverite0101
END

IF ~~ THEN BEGIN Klareverite0101
SAY @1301009
IF ~~ THEN REPLY @2301014 GOTO Klareverite0102
IF ~~ THEN REPLY @2301015 GOTO Klareverite0102
END

IF ~~ THEN BEGIN Klareverite0102
SAY @1301010
IF ~~ THEN REPLY @2301016 GOTO Klareverite0103
IF ~~ THEN REPLY @2301017 GOTO Klareinteru0101
END

IF ~~ THEN BEGIN Klareverite0103
SAY @1301010
IF ~~ THEN REPLY @2301016 GOTO Klareverite0103
IF ~~ THEN REPLY @2301017 GOTO Klareinteru0101
END
IF ~~ THEN BEGIN Klareinteru0101
SAY @1301010
IF ~~ THEN DO ~SetGlobal("#ZGemmajoined","GLOBAL",1) JoinParty()~ EXIT
END

// Partie 3 signature du contract

// Partie 4 Klare rejoinds l'equipe

// Partie 5 Klare s'en va


//////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
// Dialogues de liceciment de Klare - 02 //
//////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
BEGIN "#ZKlareP"
IF ~Global("#ZKlarejoined","GLOBAL",1)~
THEN BEGIN Klarevire0201
SAY @1302001
IF ~~ THEN REPLY @2302001 GOTO Klarevire0202
IF ~~ THEN REPLY @2302002 GOTO Klarevire0203
IF ~~ THEN REPLY @2302003 GOTO Klarevire0204
END

//Klare attend a sa position actuelle
IF ~~ THEN BEGIN Klarevire0202
SAY @1302002
IF ~~ DO ~SetGlobal("#ZKlarejoined","GLOBAL",0)~ EXIT
END

// Klare est envoyé a la couronne de cuivre
IF ~~ THEN BEGIN Klarevire0203
SAY @1302003
IF ~~ THEN REPLY @2302004 GOTO Klarevire0205
END

IF ~~ THEN BEGIN Klarevire0204
SAY @1302004
IF ~~ DO ~JoinParty()~ EXIT
END

IF ~~ THEN BEGIN Klarevire0205
SAY @1302005
IF ~~ DO ~SetGlobal("#ZKlarejoined","GLOBAL",0) SetGlobal("#ZKlaretombe","GLOBAL",1)~ EXIT
END

//////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
// Dialogues de rerecrutement - 03 //
//////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
IF ~Global("#ZKlarejoined","GLOBAL",0)~ THEN BEGIN Klareqqpart // Le NPC se trouve "quelque part" la ou la abandonner CHARNAME
SAY @1303001
IF ~~ THEN REPLY @2303001 GOTO Klarerevien // Klare reviens dans le groupe
IF ~~ THEN REPLY @2303002 GOTO Klarevire0203 // Demande a Klare d'aller au cimetiere
IF ~~ THEN REPLY @2303003 GOTO Klarefuit0401
IF ~~ THEN REPLY @2303004 EXIT
END

IF ~Global("#ZKlaretombe","GLOBAL",2)~ THEN BEGIN Klarecimetiere
SAY @1303001
IF ~~ THEN REPLY @2303001 GOTO Klarerevien // Klare reviens dans le groupe
IF ~~ THEN REPLY @2303003 GOTO Klarefuit0401
IF ~~ THEN REPLY @2303004 EXIT
END

// Le NPC reviens dans le groupe
IF ~~ THEN BEGIN Klarerevien
SAY @1303003
IF ~~ THEN DO ~SetGlobal("#ZKlarejoined","GLOBAL",1) SetGlobal("#ZKlaretombe","GLOBAL",0) JoinParty()~ EXIT // Klare reviens dans le groupe
END

//////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
// Rupture du contract - 04 //
//////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
IF ~~ THEN BEGIN Klareenemy0401
SAY @1304001
IF ~~ THEN DO ~SetGlobal("ZKlarehostile","GLOBAL",1)~ EXIT // Klare devient hostile
END

IF ~~ THEN BEGIN Klarefuit0403
SAY @1304003
IF ~~ THEN DO ~SetGlobal("#ZKlarefuit","GLOBAL",1)~ EXIT // Klare disparait a jamais
END

IF ~~ THEN BEGIN Klarefuit0401
SAY @1304002
IF ~~ THEN DO ~SetGlobal("#ZKlareafuitngry","GLOBAL",1)~ EXIT // Klare disparait a jamais
END

[Armand]

Le problème je pense est que quand tu fais le lien vers ton bloc tu es dans le dlg #ZKlare et ton bloc se trouve dans le dlg #ZKlareP . On le vois parce qu'ils sont à l'intérieur de tes BEGIN; c'est à ça que sert un BEGIN en fait ça indique d'un fichier dlg de la référence précisé est généré. Je te suggérerais une manip dans ce style sur tous les renvois au bloc Klareenemy0401 :

IF ~~ THEN REPLY @2301003 EXTERN ~#ZKlareP~ Klareenemy0401

Le mot clef EXTERN permet de se balader entre les fichiers dlg et tu devras l'utiliser chaque fois que tu veux passer de l'un à l'autre. Il doit etre par contre suivi de la référence du dlg en question comme dans l'exemple.

Voila j'ai peut être raté d'autres trucs mais avec ça ça devrait aller déja un peu mieux. Bonne chance à toi.

P.S : velchy c'est toi ?!

[Klare]

Mmmm.
Donc en fait mon "bloc" est diviser en deux sous parties et les acces ne sont pas possible de l'une a l'autre sans le fameux "EXTERN"
Parfais je tente ca dans la nuit !! Merci beaucoup Armand

(Et non desolé malgré ma malette de pseudonyme je n'ai jamais porter le nom de Velchy )

[Freddy_Gwendo]

Armand a raison.

Par ailleurs, ce genre de message :

ERROR: Cannot resolve internal symbolic label [Klareenemy0401] for DLG [#ZKLARE]

Known labels: Klareintro0101 Klareintro0102 Klareintro0103 Klareintro0104 Klares
ilence0101 Klaresilence0102 Klarepresentation0101 Klaremensonge0101 Klareverite0
101 Klareverite0102 Klareverite0103 Klareinteru0101
ERROR: postprocessing [#ZKLARE]: Failure("cannot resolve label")
Stopping installation because of error.

est systématique des erreurs d'affectation de label dans des dialogues.

Rassure-toi, ça arrive souvent quand tu jongles avec plusieurs dialogues. Au début, tu fais gaffe, et puis, le temps avançant, tu finis par faire une fausse manip.

Et encore, tu ne travailles pas sur une demi-douzaine de dialogues en même temps, avec plusieurs centaines de phrases et de répliques !

Pour limiter ce genre de mésaventures, je compile mes dialogues de plus de 1000 lignes en les fractionnant par centaines de lignes. Une fois qu'une partie est compilée sans problème, je rajoute la seconde.
Ça te permet aussi de mieux chercher la cause de l'erreur en limitant la zone de recherche.

Bon courage.


PS : essaie aussi de travailler avec des "CHAIN". Ça limite parfois ce genre de tracas.

[Armand]

Donc en fait mon "bloc" est diviser en deux sous parties et les acces ne sont pas possible de l'une a l'autre sans le fameux "EXTERN"

Oui si tu veux en fait de base un fichier d peux contenir un ou plusieur dlg (un par begin). Certains utilisent un fichier d par dlg, un fichier d pour tous les dlg, d'autres comme moi regroupent par fichier d thématiques, scènes, etc... C'est à toi de choisir en fonction de ce que tu préfère mais c'est comme tout on prend ses habitudes en codant.

Comme a pu le dire freddy plus ton fichier est gros plus l'erreur est compliqué à trouver heureusement tous les editeurs de texte ont une fonction "recherche" et des n° de lignes indiqué (indispensable vu que weidu t'indique le n° de l'erreur).

Je parlais de velchy parce que tu utilisais son prefixe. Ca te viens d'ou #Z ? Tu as prevu de t'en renserver un sur black wyrm ?

[Klare]

J'ai piquer le #Z au mod One day NPC de Genma (trouvé sur ce forum je pense) qui l'utilisais pour sa nomenclature et qui ma servit de base pour décortiquer le fonctionnement de base d'un mod.
C'est la temporairement car il me sert encore dans mes premières variables (notament dans mon fichier CRE).

Je le remplacerai bientot (car tardivement ca me ferra plus de boulot) par autre chose, et j'avoue etre interloqué par la 'reservation'? Quesako?

[Freddy_Gwendo]

Le problème, c'est pas d'identifier la ligne où ça plante, c'est d'être certain que le problème vient effectivement de cette ligne : souvent, il est lié à une erreur survenue ailleurs. Exemple typique : un oubli de " ou de ~, voir un "END" oublié à la ligne n, et WeiDU t'indique un message d'erreur à la ligne n+x !

C'est pour ça que je scinde mes gros fichiers .d (+ de 2000 lignes) pour mieux identifier les problèmes quand il y a en a. Avant de les compiler en entier...


Quant à la réservation de préfixe, tu peux la trouver ici.

C'est tout simple : tu réserves les 2 premiers caractères de tes fichiers. Ainsi tu évites les problèmes "d'écrasement" de fichiers et de variables par plusieurs modules qui par malheur utiliseraient la même nomenclature.

C'est ainsi que j'avais réservé "GW" il y a plus de 6 ans : mon mod n'est pas encore terminé, mais personne n'a utilisé ce code car il est "pris". Du coup, quand j'aurai terminé, je suis certain que mes fichiers ne se substitueront pas à ceux des autres, et vice versa.