[PRO] Attribuer un nom "descriptif" à un projectile

Regroupe tous les fichiers spl et pro
Répondre
Avatar du membre
Freddy_Gwendo
Adepte de Grondemarteau
Orbe ancien
Messages : 5877
Enregistré le : sam. 23 avr. 2011, 00:26
Localisation : Égaré dans un vortex entre Féérune et le Royaume de Diamant Éternel
Statut : Hors ligne

[PRO] Attribuer un nom "descriptif" à un projectile

.

Message par Freddy_Gwendo »

Vous avez tous créé des nouveaux projectiles et pesté contre le fait que l'IE les enregistre sous le nom de leur fichier PRO dans les fichiers projectl.ids et missile.ids.

Je me suis rappelé il y a peu la lecture d'un sujet sur un site disparu. Et j'ai voulu vérifier si mes souvenirs étaient exacts. Eh bien oui !

Du coup :

Code : Tout sélectionner

ADD_PROJECTILE ~%MOD_FOLDER%/Proj/GWArcSol.pro~ ~Arrow of Sun~				// 4-Arrow Flaming (ARROWFLM)	==>	couleurs = 67-Shiny Gold

COPY_EXISTING ~GWArcSol.pro~ ~override/GWArcSpi.pro~ 					// 4-Arrow Flaming (ARROWFLM)	==>	couleurs = 79-Light Silver
	PATCH_FOR_EACH index1 IN 0x124 0x125 0x126 0x127 0x128 0x129 0x12a BEGIN
		WRITE_BYTE %index1% 79							// Projectile colours : 79-Light Silver
	END
	PATCH_FOR_EACH index2 IN 0x12c 0x12d 0x12e 0x12f 0x130 0x131 0x132 BEGIN
		WRITE_BYTE %index2% 79							// Smoke colours : 79-Light Silver
	END
BUT_ONLY
ADD_PROJECTILE ~override/GWArcSpi.pro~ ~Arrow Spiritual~
crée respectivement les lignes GWArcSol et GWArcSpi dans projectl.ids, et Arrow of Sun et Arrow Spiritual dans le fichier missile.ids.


De même, on peut aussi modifier les dénominations du fichier missile.ids :

Code : Tout sélectionner

ACTION_FOR_EACH MMissile_Proj IN ~GWMMisBl~ ~GWMMisCy~ ~GWMMisGd~ ~GWMMisMa~ ~GWMMisPu~ ~GWMMisRd~ ~GWMMisVt~ ~GWMMisWh~ BEGIN

	COPY_EXISTING ~MAGICMIS.pro~ ~override/%MMissile_Proj%.pro~	// 37-Magic Missile (MAGICMIS)
		TO_UPPER %DEST_RES%
		WRITE_ASCIIE 0x104 "%DEST_RES%" #8			// Projectile animation (BAM)
	BUT_ONLY
	ADD_PROJECTILE ~override/%MMissile_Proj%.pro~

END

ACTION_FOR_EACH Potions_Proj IN ~GWPotnAg~ ~GWPotnBl~ ~GWPotnCy~ ~GWPotnGd~ ~GWPotnJa~ BEGIN

	COPY_EXISTING ~MAGICMIS.pro~ ~override/%Potions_Proj%.pro~	// 37-Magic Missile (MAGICMIS)
		TO_UPPER %DEST_RES%
		WRITE_SHORT 0x00a 20 					// Projectile speed (0x01 to 0xFF) : 1 à 255
		WRITE_ASCIIE 0x104 "%DEST_RES%" #8			// Projectile animation (BAM)
		PATCH_IF ("%DEST_RES%" STRING_COMPARE_CASE "GWPotnBl" = 0) BEGIN
			WRITE_LONG 0x100 (THIS BAND BNOT BIT7)		// BAM projectile flags : remove Bit7 : Enable brighten flags (Translucent)
		END
	BUT_ONLY
	ADD_PROJECTILE ~override/%Potions_Proj%.pro~

END


COPY_EXISTING ~missile.ids~ ~override~

	REPLACE_TEXTUALLY ~GWMMisBl~ ~Magic Missile Blue~
	REPLACE_TEXTUALLY ~GWMMisCy~ ~Magic Missile Cyan~
	REPLACE_TEXTUALLY ~GWMMisGd~ ~Magic Missile Gold~
	REPLACE_TEXTUALLY ~GWMMisMa~ ~Magic Missile Magenta~
	REPLACE_TEXTUALLY ~GWMMisPu~ ~Magic Missile Purple~
	REPLACE_TEXTUALLY ~GWMMisRd~ ~Magic Missile Red~
	REPLACE_TEXTUALLY ~GWMMisVt~ ~Magic Missile Green~
	REPLACE_TEXTUALLY ~GWMMisWh~ ~Magic Missile White~
	REPLACE_TEXTUALLY ~GWPotnAg~ ~Potion Silver~
	REPLACE_TEXTUALLY ~GWPotnBl~ ~Potion Blue~
	REPLACE_TEXTUALLY ~GWPotnCy~ ~Potion Cyan~
	REPLACE_TEXTUALLY ~GWPotnGd~ ~Potion Gold~
	REPLACE_TEXTUALLY ~GWPotnJa~ ~Potion Yellow~
BUT_ONLY
:!: ATTENTION cependant, la modification du missile.ids ne fonctionne que dans l'ordre d'apparition des projectiles. Dans le cas précédent

Code : Tout sélectionner

COPY_EXISTING ~missile.ids~ ~override~

	REPLACE_TEXTUALLY ~GWMMisCy~ ~Magic Missile Cyan~
	REPLACE_TEXTUALLY ~GWMMisBl~ ~Magic Missile Blue~
...
plante la procédure d'installation.

Et le résultat :
Image
CARPE DIEM...Co-modérateur de La Forge et de La Chambre des Scribes
Moddeur qui s'arrache les cheveux...
Répondre

Retourner vers « Sorts et projectiles »

Qui est en ligne

Utilisateurs parcourant ce forum : Aucun utilisateur enregistré et 3 invités